blob: f5bbedb3feda504d1eda3d3f594ae810a2a997d6 (
plain)
1
2
3
4
5
6
7
8
9
10
11
12
13
14
15
16
17
18
19
20
21
22
23
24
25
26
27
28
29
30
31
32
33
34
35
36
37
38
39
40
41
42
43
44
45
46
47
48
49
50
51
52
53
54
55
56
57
58
59
60
61
62
63
64
65
66
67
68
69
70
71
72
73
74
75
76
77
78
79
80
81
82
83
84
85
86
87
88
89
90
91
|
#
# InspIRCd -- Internet Relay Chat Daemon
#
# Copyright (C) 2013-2014 Peter Powell <petpow@saberuk.com>
#
# This file is part of InspIRCd. InspIRCd is free software: you can
# redistribute it and/or modify it under the terms of the GNU General Public
# License as published by the Free Software Foundation, version 2.
#
# This program is distributed in the hope that it will be useful, but WITHOUT
# ANY WARRANTY; without even the implied warranty of MERCHANTABILITY or FITNESS
# FOR A PARTICULAR PURPOSE. See the GNU General Public License for more
# details.
#
# You should have received a copy of the GNU General Public License
# along with this program. If not, see <http://www.gnu.org/licenses/>.
#
BEGIN {
require 5.10.0;
}
package make::common;
use feature ':5.10';
use strict;
use warnings FATAL => qw(all);
use Exporter qw(import);
use File::Spec::Functions qw(rel2abs);
our @EXPORT = qw(get_cpu_count
get_version
module_installed);
sub get_version {
state %version;
return %version if %version;
# Attempt to retrieve version information from src/version.sh
chomp(my $vf = `sh src/version.sh 2>/dev/null`);
if ($vf =~ /^InspIRCd-([0-9]+)\.([0-9]+)\.([0-9]+)(?:\+(\w+))?$/) {
%version = ( MAJOR => $1, MINOR => $2, PATCH => $3, LABEL => $4 );
}
# Attempt to retrieve missing version information from Git
chomp(my $gr = `git describe --tags 2>/dev/null`);
if ($gr =~ /^v([0-9]+)\.([0-9]+)\.([0-9]+)(?:-\d+-g(\w+))?$/) {
$version{MAJOR} //= $1;
$version{MINOR} //= $2;
$version{PATCH} //= $3;
$version{LABEL} = $4 if defined $4;
}
# The user is using a stable release which does not have
# a label attached.
$version{LABEL} //= 'release';
# If any of these fields are missing then the user has deleted the
# version file and is not running from Git. Fill in the fields with
# dummy data so we don't get into trouble with undef values later.
$version{MAJOR} //= '0';
$version{MINOR} //= '0';
$version{PATCH} //= '0';
return %version;
}
sub module_installed($) {
my $module = shift;
eval("use $module;");
return !$@;
}
sub get_cpu_count {
my $count = 1;
if ($^O =~ /bsd/) {
$count = `sysctl -n hw.ncpu 2>/dev/null` || 1;
} elsif ($^O eq 'darwin') {
$count = `sysctl -n hw.activecpu 2>/dev/null` || 1;
} elsif ($^O eq 'linux') {
$count = `getconf _NPROCESSORS_ONLN 2>/dev/null` || 1;
} elsif ($^O eq 'solaris') {
$count = `psrinfo -p 2>/dev/null` || 1;
}
chomp($count);
return $count;
}
1;
|
